Native code.
Familiar syntax.
No pointers.

interface Shape {
    f64 area() const
}

struct Circle : Shape {
    f64 radius

    f64 area() const {
        ret 3.14159 * radius * radius
    }
}

// Compiled once for each type: no boxing, no virtual calls.
f64 total<T : Shape>(list<T> shapes) {
    f64 sum = 0.0
    for (T shape in shapes) {
        sum += shape.area()
    }
    ret sum
}

i32 main() {
    list<Circle> circles
    for (i32 i = 1; i <= 3; i++) {
        Circle c
        c.radius = f64(i)
        circles.add(c)
    }
    println("{:.2f}", total(circles))
    ret 0
}

$ cromo run generics.cro
43.98

// A lambda captures by value, with ref or with move.
list<i64> select(list<i64> values, func(i64) bool test) {
    list<i64> result
    for (i64 v in values) {
        if (test(v)) {
            result.add(v)
        }
    }
    ret result
}

i32 main() {
    list<i64> values
    for (i64 i = 1; i <= 10; i++) {
        values.add(i)
    }
    i64 limit = 7
    i64 sum = 0
    list<i64> big = select(values, [limit](i64 x) bool { ret x > limit })
    select(values, [ref sum](i64 x) bool {
        sum += x
        ret false
    })
    println("{} above {}, sum {}", big.len(), limit, sum)
    ret 0
}

$ cromo run lambdas.cro
3 above 7, sum 55

i32 main() {
    map<string, i32> stock
    stock["apples"] = 12
    stock["pears"] += 3  // a missing key starts from 0
    i32[7] week          // a fixed-size array, where it is declared
    week[0] = stock["apples"]
    for (string item, i32 count in stock) {
        println("{:<8}{:>4}", item, count)
    }
    string report = format("{} items, monday {}", stock.len(), week[0])
    println("{}", report)
    ret 0
}

$ cromo run collections.cro
apples    12
pears      3
2 items, monday 12

import std.fs

struct Config {
    string path
    i32 port
}

Config load(string path) {
    Config config
    config.path = path.copy()
    config.port = i32(fs.readText(path))
    ret config
}

i32 main() {
    try {
        Config config = load("port.txt")
        println("listening on {}", config.port)
    } catch (Exception e) {
        eprintln("cannot start: {}", e.message())
        ret 1
    } finally {
        println("bye")
    }
    ret 0
}

$ cromo run errors.cro
cannot start: cannot read 'port.txt': no such file or folder
bye

import unsafe

extern "user32" {
    i32 MessageBoxA(addr window, addr text, addr title, u32 kind)
}

i32 main() {
    addr none
    string text = "Hello from Cromo"
    MessageBoxA(none, text.cstring(), "cromo".cstring(), 0)
    ret 0
}

$ cromo run c_interop.cro
# a message box opens; user32.dll was checked for MessageBoxA at compile time